MinecraftForge/settings.gradle

pluginManagement {
    if (new File('forgedev/settings.gradle').exists())
        includeBuild 'forgedev'

    includeBuild('build-logic')

    repositories {
        gradlePluginPortal()
        maven { url = 'https://maven.minecraftforge.net/' }
        //mavenLocal()
    }
}

plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention' version '1.0.0'
}

rootProject.name = 'forge'

include 'fmlloader'
include 'fmlloader-tests'
include 'fmlcore'
include 'mclanguage'
include 'javafmllanguage'
include 'lowcodelanguage'
include 'fmlearlydisplay'
include 'forge-transformers'
include 'forge-examiner'
include 'forge-tests'
include 'forge-mdk'

enableFeaturePreview 'TYPESAFE_PROJECT_ACCESSORS'

dependencyResolutionManagement.versionCatalogs {
    register('bootLibs') {
        description = 'Java, Minecraft, and MCP versions'
        from(files('minecraft.versions.toml'))
    }

    register('buildLibs') {
        description = 'Libraries used solely during the build and publish process.'
        from(files('gradle/buildLibs.versions.toml'))
    }

    register('libs') {
        description = 'Libraries used by Forge and its subprojects.'
    }

    register('earlyDisplayLibs') {
        from(files('gradle/earlyDisplayLibs.versions.toml'))
    }

    register('earlyDisplayTestLibs') {
        from(files('gradle/earlyDisplayTestLibs.versions.toml'))
    }
}