mirror of
https://github.com/MinecraftForge/MinecraftForge.git
synced 2026-11-20 04:09:51 +00:00
87 lines
3.4 KiB
Groovy
87 lines
3.4 KiB
Groovy
import net.minecraftforge.forgedev.legacy.tasks.JarJarMetadataOptions
|
|
|
|
plugins {
|
|
id 'net.minecraftforge.forge.build.convention'
|
|
alias libs.plugins.apt
|
|
}
|
|
|
|
gradleutils.displayName = 'FMLLoader'
|
|
description = 'Mod Locator and manager for Minecraft Forge.'
|
|
|
|
dependencies {
|
|
// TODO [FMLLoader] Figure out a better way to lock transitive dependencies to the explicit versions shipped by the installer
|
|
api(libs.bundles.asm ){ transitive = false } // Needed by all the black magic
|
|
api(libs.forgespi ){ transitive = false }
|
|
api(libs.mergetool.api ){ transitive = false }
|
|
api(libs.log4j.api ){ transitive = false }
|
|
api(libs.slf4j.api ){ transitive = false }
|
|
api(libs.guava ){ transitive = false }
|
|
api(libs.gson ){ transitive = false }
|
|
api(libs.maven.artifact ){ transitive = false }
|
|
api(libs.apache.commons ){ transitive = false }
|
|
api(libs.bundles.night.config){ transitive = false }
|
|
api(libs.modlauncher ){ transitive = false }
|
|
api(libs.mojang.logging ){ transitive = false }
|
|
api(libs.jarjar.selector ){ transitive = false }
|
|
api(libs.jarjar.meta ){ transitive = false }
|
|
|
|
implementation(libs.jopt.simple ){ transitive = false }
|
|
implementation(libs.securemodules ){ transitive = false }
|
|
implementation(libs.accesstransformers ){ transitive = false }
|
|
implementation(libs.terminalconsoleappender){ transitive = false }
|
|
implementation(libs.roimfs ){ transitive = false }
|
|
|
|
// Needed because we have a custom log4j plugin, and they removed package scanning and require a data file to be generated
|
|
implementation(libs.log4j.core ){ transitive = false }
|
|
annotationProcessor(libs.bundles.log4j){ transitive = false }
|
|
}
|
|
|
|
convention.manifest('net/minecraftforge/fml/loading/', [
|
|
'Automatic-Module-Name': 'net.minecraftforge.fmlloader',
|
|
'Forge-Module-Layer' : 'boot'
|
|
])
|
|
|
|
convention.publish()
|
|
|
|
final forgeJson = convention.forgeVersionJson {
|
|
outputFile = file('src/main/resources/forge_version.json')
|
|
}
|
|
|
|
final jarJarJson = tasks.register('jarJarOptionsJson', JarJarMetadataOptions) {
|
|
metadataFile = file('src/main/resources/jarjar_options.json')
|
|
// This is resolved too early by cpw.mods.modlauncher.TransformationServicesHandler.discoverServices(DiscoveryData) But eventually...
|
|
//add(libs.mixin, 'org/spongepowered/asm/mixin/Mixin.class')
|
|
add(libs.mixinextras.forge) {
|
|
containedJarMetadata {
|
|
path = ''
|
|
}
|
|
resource = 'com/llamalad7/mixinextras/platform/forge/MixinExtrasConfigPlugin.class'
|
|
layer = 'GAMELIBRARY'
|
|
id = 'mixinextras'
|
|
nested = true
|
|
}
|
|
}
|
|
|
|
tasks.named('generateResources') {
|
|
dependsOn(
|
|
tasks.named('eclipseJdt'),
|
|
tasks.named('eclipseJdtApt'),
|
|
tasks.named('eclipseFactorypath'),
|
|
forgeJson,
|
|
jarJarJson
|
|
)
|
|
}
|
|
|
|
eclipse.classpath {
|
|
// We need to set the default output directory for the log4j annotation processor
|
|
// Ideally we'd just set the value, but the eclipse plugin deduplicates the output directories
|
|
// So we have to do a hacky whenMerged
|
|
//defaultOutputDir = file('bin/main')
|
|
file.whenMerged {
|
|
entries.each { entry ->
|
|
if (entry.kind == 'output' && entry.hasProperty('path'))
|
|
entry.path = 'bin/main'
|
|
}
|
|
}
|
|
}
|