Files
MCCustomSkinLoader/Forge/build.gradle
T
Alexander Xia f669d095b6 Add Support for 1.13!
Thanks for MinecraftForge/MCPConfig.
2018-07-25 21:06:16 +08:00

90 lines
2.5 KiB
Groovy

buildscript {
repositories {
mavenCentral()
jcenter()
maven {
name = "forge"
url = "http://files.minecraftforge.net/maven"
}
}
dependencies {
classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
}
}
apply plugin: 'net.minecraftforge.gradle.forge'
ext.MINECRAFT_VERSION = "1.12.2"
ext.FORGE_VERSION = "14.23.3.2655"
ext.MAPPING_VERSION = "snapshot_20180505"
ext.MINECRAFT_FULL_VERSIONS = "1.8,1.8.8,1.8.9,1.9,1.9.4,1.10,1.10.2,1.11,1.11.2,1.12,1.12.1,1.12.2"
ext.snapshot = !(rootProject.ext.config.snapshot == "" || rootProject.ext.config.snapshot == "0" || rootProject.ext.config.snapshot == 0)
archivesBaseName = "CustomSkinLoader_Forge"
version = rootProject.ext.config.version + rootProject.ext.config.dev_version + (snapshot ? "-SNAPSHOT-" + System.getenv("CIRCLE_BUILD_NUM") : "")
group = "customskinloader"
sourceCompatibility = targetCompatibility = 1.6
compileJava {
sourceCompatibility = targetCompatibility = 1.6
}
jar {
manifest {
attributes 'FMLCorePlugin': 'customskinloader.forge.ForgePlugin'
attributes 'FMLCorePluginContainsFMLMod': true
}
exclude 'net/minecraft/client/renderer/texture/NativeImage.class'
}
sourceSets {
main {
java {
//Common
srcDir '../Common/source'
//Forge
srcDir 'source'
}
resources {
//Common
srcDir '../Common/resource'
//Forge
srcDir 'resource'
}
}
}
minecraft {
version = MINECRAFT_VERSION + "-" + FORGE_VERSION
runDir = "run"
mappings = MAPPING_VERSION
replace '@MOD_VERSION@', rootProject.ext.config.version
replace '@MOD_FULL_VERSION@', project.version
replaceIn 'CustomSkinLoader.java'
replaceIn 'ForgeMod.java'
}
processResources {
expand([
modVersion : rootProject.ext.config.version,
modFullVersion: project.version,
mcVersion : MINECRAFT_VERSION,
mcFullVersions: MINECRAFT_FULL_VERSIONS,
forgeVersion : FORGE_VERSION,
gitVersion : System.getenv("CIRCLE_SHA1"),
buildUrl : System.getenv("CIRCLE_BUILD_URL")
])
}
task afterBuild {
doLast {
//copyBuildFile
copy {
from 'build/libs'
into '../build/libs'
include '**/*.jar'
exclude '**/*-sources.jar'
}
}
}
build.finalizedBy afterBuild