Files
BloodArsenal/build.gradle
T
2021-12-13 08:50:20 -06:00

159 lines
4.6 KiB
Groovy

buildscript {
repositories {
mavenCentral()
maven {
name = "GT"
url = "https://gregtech.overminddl1.com/"
}
maven {
name = "sonatype"
url = "https://oss.sonatype.org/content/repositories/snapshots/"
}
maven {
name = "jitpack"
url = "https://jitpack.io"
}
maven {
url = "https://plugins.gradle.org/m2/"
}
}
dependencies {
classpath 'com.github.GTNewHorizons:ForgeGradle:1.2.4'
classpath 'org.ajoberstar:gradle-git:0.10.1'
classpath "de.undercouch:gradle-download-task:3.1.2"
}
}
import de.undercouch.gradle.tasks.download.Download
apply plugin: 'forge'
apply plugin: 'signing'
ext.configFile = file "build.properties"
configFile.withReader {
def prop = new Properties()
prop.load(it)
project.ext.config = new ConfigSlurper().parse prop
}
version = config.mc_version + "-" + config.mod_version + "-" + config.build_number
group= config.package_group
archivesBaseName = config.mod_name
import org.ajoberstar.grgit.Grgit
def gitHash = 'unknown'
if (new File(projectDir, '.git').exists()) {
def repo = Grgit.open(project.file('.'))
gitHash = repo.log().find().abbreviatedId
}
repositories {
maven { //Tinker's and Mantle
name 'DVS1 Maven FS'
url 'https://dvs1.progwml6.com/files/maven'
}
maven {
name = "gt"
url = "https://gregtech.overminddl1.com/"
}
ivy {
name = "gtnh_download_source"
artifactPattern("http://downloads.gtnewhorizons.com/Mods_for_Jenkins/[module]-[revision].[ext]")
}
maven {
name = "jitpack"
url = "https://jitpack.io"
}
}
minecraft {
version = "1.7.10-10.13.4.1614-1.7.10"
runDir = "eclipse"
replaceIn "BloodArsenal.java"
replace "@VERSION@", config.mod_version + "-" + config.build_number
}
dependencies {
compile "com.github.GTNewHorizons:NotEnoughItems:master-SNAPSHOT:dev"
compile "com.github.GTNewHorizons:ForgeMultipart:master-SNAPSHOT:dev"
compile "com.github.GTNewHorizons:waila:master-SNAPSHOT:dev"
compile("com.github.GTNewHorizons:TinkersConstruct:master-SNAPSHOT:dev") {
transitive = false
}
compile "mantle:Mantle:1.7.10-0.3.2.jenkins187:deobf"
compile "info.amerifrance.guideapi:Guide-API:" + config.mc_version + "-" + config.guideapi_version + ":deobf"
compile "com.azanor.baubles:Baubles:1.7.10-" + config.baubles_version + ":deobf"
compile fileTree(dir: 'libs', include: '*.jar')
}
processResources
{
inputs.property "version", project.version
inputs.property "mcversion", project.minecraft.version
from(sourceSets.main.resources.srcDirs) {
include '**/*.info'
include '**/*.properties'
expand 'version': project.version, 'mcversion': project.minecraft.version
}
from(sourceSets.main.resources.srcDirs) {
exclude '**/*.info'
exclude '**/*.properties'
exclude '**/*.db'
}
}
task getThaumcraft(type: Download) {
onlyIf {
!file("libs/Thaumcraft-deobf-1.7.10-4.2.3.5.jar").exists()
}
src 'http://downloads.gtnewhorizons.com/Mods_for_Jenkins/Thaumcraft-1.7.10-4.2.3.5-deobf.jar'
dest file("libs/Thaumcraft-deobf-1.7.10-4.2.3.5.jar")
mustRunAfter "deobfBinJar"
mustRunAfter "repackMinecraft"
}
task getBloodMagic(type: Download, dependsOn: "getThaumcraft") {
onlyIf {
!file("libs/BloodMagic-1.7.10-1.3.3-17-deobf.jar").exists()
}
src 'http://downloads.gtnewhorizons.com/Mods_for_Jenkins/BloodMagic-1.7.10-1.3.3-17-deobf.jar'
dest file("libs/BloodMagic-1.7.10-1.3.3-17-deobf.jar")
mustRunAfter "deobfBinJar"
mustRunAfter "repackMinecraft"
}
tasks.setupCIWorkspace.dependsOn getBloodMagic
tasks.setupDevWorkspace.dependsOn getBloodMagic
tasks.setupDecompWorkspace.dependsOn getBloodMagic
tasks.compileJava.dependsOn getBloodMagic
task deobfJar(type: Jar) {
from(sourceSets.main.output)
classifier = 'deobf'
tasks.build.dependsOn deobfJar
tasks.withType(JavaCompile) { task ->
task.options.encoding = 'UTF-8'
}
}
task signJar(dependsOn: 'reobf'){
doLast {
ant.signjar(
destDir: jar.destinationDir,
jar: jar.getArchivePath(),
alias: findProperty('keyStoreAlias') ?: '',
keystore: findProperty('keyStore') ?: '',
storepass: findProperty('keyStorePass') ?: '',
digestalg: findProperty('signDigestAlg') ?: '',
tsaurl: findProperty('signTSAurl') ?: '',
verbose: true
)
}
}